Best How To :

Try using this function for reading images.

CFimage tag or imageNew() can have issues while trying to read image files which are corrupted or files saved with changed extensions (background transparent .png files saved as .jpeg) while uploading.

I think the main problem with these files is that there is a chance coldfusion doesn't throw an error of any sort when we try to read files mentioned above.

<cfscript>
    public function readImage(fullpath){
        //trying java imageio
        var imageFile = createObject("java", "java.io.File").init(fullpath); 
        // read the image into a BufferedImage
        var ImageIO = createObject("java", "javax.imageio.ImageIO");
        try {
            var bi = ImageIO.read(imageFile);
            return ImageNew(bi);
        } catch(any e) {
        //try for bad formatted images
            //create java file object, passing in path to image
            var imageFile = createObject("java","java.io.File").init(fullpath);
            //create a FileSeekableStream, passing in the image file we created
            var fss = createObject("java","com.sun.media.jai.codec.FileSeekableStream").init(imageFile);
            //create ParameterBlock object and initialize it (call constructor)
            var pb = createObject("java","java.awt.image.renderable.ParameterBlock").init();
            //create JAI object that will ultimately do the magic we need
            var JAI = createObject("java","javax.media.jai.JAI");
            try {
                //pass in FileSeekableStream
                pb.add(fss);

                //use the JAI object to create a buffered jpeg image.
                var buffImage = local.JAI.create("jpeg", pb).getAsBufferedImage();

                //pass the buffered image to the ColdFusion imagenew()
                var New_Image = imagenew(buffImage);

                //make sure we close the stream
                fss.close();
                return New_Image;
            } catch (any e) {
                if (isDefined("fss")) {
                    fss.close();
                }
                rethrow;
            }
        }
    }
</cfscript>